Bank Precompile

Address: 0x0000000000000000000000000000000000001001

Do not use the Bank precompile as an IBC or tokenfactory integration path. This page covers native SEI (usei) only. IBC is disabled in both directions. Tokenfactory is not supported for new development. See IBC is disabled and Tokenfactory is not supported.

The Bank precompile exposes the Bank Module balance for native SEI. It also lets an EVM caller send SEI to a native sei1... address.

Functions

/// Returns an account's Bank Module balance for the requested denomination.
function balance(
    address account,
    string memory denom
) external view returns (uint256 amount);

/// Sends the attached native SEI to a native Sei address.
function sendNative(
    string memory toNativeAddress
) external payable returns (bool success);

The examples below use balance() with usei. They do not cover arbitrary Bank Module denominations.

Read-only query methods

The Bank precompile also exposes a set of read-only query methods that mirror the Bank Module’s gRPC queries.

/// Returns the spendable (unlocked) balances of an account, paginated.
function spendableBalances(
    address acc,
    bytes memory pageKey
) external view returns (Coin[] memory balances, bytes memory nextKey);

/// Returns the total supply of a single denomination.
function supply(
    string memory denom
) external view returns (uint256 response);

/// Returns the total supply of every denomination, paginated.
function totalSupply(
    bytes memory pageKey
) external view returns (Coin[] memory supply, bytes memory nextKey);

/// Returns the Bank Module parameters.
function params() external view returns (Params memory params);

/// Returns the metadata for a single denomination.
function denomMetadata(
    string memory denom
) external view returns (Metadata memory metadata);

/// Returns the metadata for every denomination, paginated.
function denomsMetadata(
    bytes memory pageKey
) external view returns (Metadata[] memory metadatas, bytes memory nextKey);

supply and totalSupply are distinct: supply(denom) returns the total supply of a single denomination as a uint256, while totalSupply(pageKey) returns a paginated list of every denomination’s supply. The supporting structs are:

struct Coin {
    uint256 amount;
    string denom;
}

struct SendEnabled {
    string denom;
    bool enabled;
}

struct Params {
    SendEnabled[] sendEnabled;
    bool defaultSendEnabled;
}

struct DenomUnit {
    string denom;
    uint32 exponent;
    string[] aliases;
}

struct Metadata {
    string description;
    DenomUnit[] denomUnits;
    string base;
    string display;
    string name;
    string symbol;
}

Methods that accept a pageKey argument are paginated. Pass empty bytes (0x) to request the first page, then pass the returned nextKey to fetch the next page. An empty nextKey means there are no more pages.

const account = '0x1234567890123456789012345678901234567890';

const [balances, nextKey] = await readBank.spendableBalances(account, '0x');
for (const coin of balances) {
  console.log(`${coin.amount} ${coin.denom}`);
}

const seiSupply = await readBank.supply('usei');
console.log(`${ethers.formatUnits(seiSupply, 6)} SEI total supply`);

const metadata = await readBank.denomMetadata('usei');
console.log(metadata.name, metadata.symbol);

Setup

npm install ethers @sei-js/precompiles@^3

import { ethers } from 'ethers';
import {
  BANK_PRECOMPILE_ABI,
  BANK_PRECOMPILE_ADDRESS,
} from '@sei-js/precompiles';

const provider = new ethers.BrowserProvider(window.ethereum);
const signer = await provider.getSigner();

const readBank = new ethers.Contract(
  BANK_PRECOMPILE_ADDRESS,
  BANK_PRECOMPILE_ABI,
  provider,
);

const writeBank = new ethers.Contract(
  BANK_PRECOMPILE_ADDRESS,
  BANK_PRECOMPILE_ABI,
  signer,
);

Query a native SEI balance

Bank Module queries return native SEI in usei, where 1 SEI equals 1,000,000 usei.

const account = '0x1234567890123456789012345678901234567890';
const balanceUsei = await readBank.balance(account, 'usei');

console.log(`${ethers.formatUnits(balanceUsei, 6)} SEI`);

You can make the same query from Solidity:

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IBankPrecompile {
    function balance(
        address account,
        string memory denom
    ) external view returns (uint256 amount);
}

contract SeiBalanceReader {
    IBankPrecompile private constant BANK =
        IBankPrecompile(0x0000000000000000000000000000000000001001);

    function nativeSeiBalance(address account) external view returns (uint256) {
        return BANK.balance(account, "usei");
    }
}

Send native SEI to a native address

sendNative() accepts SEI through msg.value. Use an 18-decimal EVM value for the transaction.

const recipient = 'sei1qqqqqqqqqqqqqqqqqqqqqqqqqqqqqqqq6s8dpw';

const transaction = await writeBank.sendNative(recipient, {
  value: ethers.parseEther('0.1'),
});

await transaction.wait();

From Solidity, forward the attached value to the precompile:

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

interface IBankPrecompile {
    function sendNative(
        string memory toNativeAddress
    ) external payable returns (bool success);
}

contract NativeSeiSender {
    IBankPrecompile private constant BANK =
        IBankPrecompile(0x0000000000000000000000000000000000001001);

    function sendToNativeAddress(
        string calldata recipient
    ) external payable {
        require(msg.value > 0, "No SEI attached");
        require(
            BANK.sendNative{value: msg.value}(recipient),
            "Transfer failed"
        );
    }
}

Validate the recipient before you send SEI. A successful transaction cannot be reversed.

Overview

Essentials

seid CLI

Frontend Development

Smart Contracts

sei-js Library

Videos

Ecosystem Tutorials

Reference

Hardware Wallets

Functions

Read-only query methods

Setup

Query a native SEI balance

Send native SEI to a native address

​Functions

​Read-only query methods

​Setup

​Query a native SEI balance

​Send native SEI to a native address

Functions

Read-only query methods

Setup

Query a native SEI balance

Send native SEI to a native address